Tea-Qt5

Od pewnego czasu, popularny edytor tekstu (i jeszcze trochę) można zbudować z użyciem bądź to Qt4, bądź to Qt5. W repozytoriach Archa dostępna jest ta pierwsza wersja. Pomijając cel rozwijania oprogramowania opartego o zarzucony już framework, zwłaszcza, gdy istnieje już możliwość zbudowania go w oparciu o nowszy, to wydaje się, że w niektórych środowiskach wersja oparta o Qt5 po prostu lepiej wygląda. Poniżej zatem przepis na zbudowanie tea w wersji qt5.
Najłatwiej będzie ściągnąć tarball istniejącej w repozytorium community paczki i przejść do utworzonego katalogu - najprościej:
yaourt -G tea && cd tea
Wymieniamy istniejący tam plik PKGBUILD na poniższy:
# $Id: PKGBUILD 151990 2015-12-10 04:11:05Z foutrelis $
# Maintainer: pavbaranov (only for Qt5 version)
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Michal Kaliszka <desmont@gmail.com>
# Contributor: Zsolt Varadi <sysop_xxl@fibermail.hu>

pkgname=tea-qt5
_pkgname=tea
pkgver=41.1.0
pkgrel=1
pkgdesc="A Qt-based text editor for Linux and *BSD. With an ultimate small size TEA provides you hundreds of functions."
arch=('i686' 'x86_64')
url="http://semiletov.org/tea/"
license=('GPL')
depends=('qt5-declarative' 'aspell' 'hunspell')
install=tea.install
source=(http://semiletov.org/tea/dloads/tea-$pkgver.tar.bz2
        tea.desktop)
md5sums=('8a41da9884f98b8ca6f57296243f8fbc'
         '377ace3363124f4c086de0babb820761')

prepare() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
#  sed -i 's|i + j|(int)(i + j)|' textproc.cpp
  sed -i 's|/usr/local|/usr|g' src.pro
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  qmake-qt5
  make
}

package(){
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make INSTALL_ROOT="${pkgdir}" install
  install -Dm644 "${srcdir}/tea.desktop" "${pkgdir}/usr/share/applications/tea.desktop"
  install -Dm644 icons/tea_icon_v2.png "${pkgdir}/usr/share/pixmaps/tea.png"
}

Wydajemy komendę:
makepkg -sirc
i cieszymy się tea-qt5.

Komentarze

Popularne posty z tego bloga

Brak możliwości aktualizacji lub instalacji pakietów - zablokowana baza

Radzimy sobie z: GPG: odbiór z serwera kluczy nie powiódł się: brak dirmngr

Ukryte sztuczki Firefox